intfiction.org

"Ran Over"

Include Speech Motivations by Mike Ciul.

Highway is a room. Jay is a man in highway. Bob is a man in highway.
Bob wears a coat. Jay carries a joint. God is a subject.

The description of the player is "You're completely naked, and still smarting from your fall out of heaven."

For getting attention of Bob when Bob is not expected to respond:
   forget the concerns of Bob.

First for speaking out loud of something (called the subject matter):
   Repeat through Table of Responses:
      if the speaker entry is the person asked and the subject entry is the subject matter:
         say response entry;
         say paragraph break;
         rule succeeds;
   continue the activity.

For speaking out loud when Bob is the person asked:
   say "Bob shrugs."

For getting attention of Jay when Jay is not expected to respond:
   If the new subject matter is Jay or the new subject matter is Bob:
      confirm motivation of Jay;
   otherwise if someone is expected to respond:
      forget the concerns of Jay;
   otherwise:
      confirm motivation of Jay.
      
For speaking out loud of something (called the subject matter) when Jay is the person asked:
   say "Jay expounds at great length, with multiple interjections of colorful profanity, on the subject of [the subject matter], but at the end you're still not sure how he feels."

For printing the name of Jay when the speaking out loud activity is going on and the person asked is Jay:
   say "himself";

Table of Responses
speaker (object)   subject (object)   response (text)
yourself   joint   "You comment on Jay's joint."
yourself   yourself   "'What's the matter? You never saw a naked black man before?' you say."
yourself   coat   "You tell [the current interlocutor] that you just want to borrow the coat until you can find some other clothes."
Bob   Jay   "Bob smiles and pats his friend on the back."
Bob   joint   "Bob raises his eyebrows."
Bob   God   "Bob shakes his head."
Bob   Bob   "Bob grins and thumps his chest."
Bob   yourself   "Bob tries not to look at your nakedness."
Jay   joint   "'Dude, have some! First one's free!'"
Jay   coat   "'Dude, [if jay is expected to respond]what are you thinking? My man doesn't want your dick rubbing all over the inside of his armor!'[otherwise]why you eyeing my man's coat?' Jay yells at you."
Jay   yourself   "'I'm not staring at a naked black man. I'm staring at naked black man who just [italic type]fell out of the f***ing sky![roman type]'"

First for speaking out loud of yourself when the person asked is Jay and Jay is not expected to respond:
   say "Jay tries to pretend that he's not staring at your nakedness.";

For speaking out loud of the coat when Bob is the person asked:
   say "Bob removes his coat and hands it to you.";
   end the story finally saying "You are no longer naked."

test me with "x bob/ask jay about joint/x me/ask jay about me/x coat/ask jay about coat/tell jay about coat/ask jay for coat/ask bob about jay/ask bob about joint/tell bob about god/ask bob about bob/ask bob about me/ask bob about joint/ask bob for coat"