intfiction.org

There is room.

Here is a poem. It has description "'Look behind you!'".

The portal is a thing.

Understand "look behind [yourself]" as looking behind. Looking behind is an action applying to one thing.

Check looking behind yourself:
   if we have not examined the poem or the portal is on-stage, try examining south instead.
   [Just to trigger the standard "You see nothing unexpected in that direction." error message.]
   
After looking behind yourself:
   now the portal is in the location;
   say "You find an immense inter-dimensional portal has opened up behind you!"

The Library is a room. "A charming Edwardian Library. The door to the pantry is to the west[if the glowing portal is in the Library]. You can also go north through the glowing portal[end if]."

The Pantry is west of the Library. "Empty shelves here."

The scented piece of paper is in the Library.  "A piece of pink, scented paper is lying here." The description is "Pink and scented -- and there's writing on it." Understand "pink" and "poem" and "writing" as the paper.

The glowing portal is a thing.  "In the north wall is  a glowing portal." The description is "It's impressive. It's embedded in the north wall." The glowing portal is fixed in place.

The Amusement Park is a room. "Wow -- look at all the rides! You can go south to return to the Library." The Library is south of the Park. North of the Library is nowhere.

Understand the command "read" as something new.

Reading is an action applying to one thing and requiring light. Understand "read [something]" as reading.

Carry out reading:
   say "Nothing is printed on [the noun]."
   
Instead of reading the scented paper:
   if the player does not carry the paper:
      say "(first picking up the piece of paper)[line break]";
      now the player carries the paper;
   say "The paper says, 'Roses are red, violets are blue, this stupid poem doesn't even rhyme.'";
   if the glowing portal is not in the Library:
      now the glowing portal is in the Library;
      if the player is in the Library:
         say "[line break]A burst of blue light erupts behind you."
   
Instead of going north in the Library:
   if the glowing portal is in the Library:
      say "";
      now the player is in the Amusement Park;
   otherwise:
      continue the action.
      
Instead of entering the glowing portal, try going north.